type
  TForm1 = class(TForm)
    . . .
    cbColors: TComboBox;
    chbShowColorValues: TCheckBox;
    . . .
  private
    { Private declarations }
    // Отображать компоненты цвета
    FShowColorValues: Boolean;
    procedure PopulateColorsList;
  public
    { Public declarations }
  end;

// Заполнение списка значениями от 0 до 256
procedure TForm1.PopulateColorsList;
var
  i: Integer;
begin
  with cbColors do
  begin
    Items.BeginUpdate;
    try
      Clear;
      for i:= 0 to 256 do
        Items.Add(IntToStr(i));
      ItemIndex:= 0; 
    finally
      Items.EndUpdate;
    end;
  end;
end;

procedure TForm1.cbColorsDrawItem(Control: TWinControl; Index: Integer;
  Rect: TRect; State: TOwnerDrawState);
var
  R: TRect;
  C, AColor: TColor;
  P: TPoint;
  S: String;
begin
  AColor:= AcadColorToColor(Index); // Получание цвета в формате TColor
  with cbColors.Canvas do
  begin
    // Залить прямоугольник фоновым цветом
    C:= Brush.Color;
    Brush.Color:= cbColors.Color;
    FillRect(Rect);
    // Залить прямоугольник цвета
    R:= Rect;
    R.Right:= R.Bottom - R.Top + R.Left;
    InflateRect(R, -2, -2);
    Brush.Color:= AColor;
    FillRect(R);
    // Обводка прямоугольника цвета
    Brush.Color:= clBlack;
    FrameRect(R);
    // Залить прямоугольник фокуса
    Brush.Color:= C;
    R:= Rect;
    R.Left:= R.Bottom - R.Top + R.Left;
    FillRect(R);
    // Показать текст
    R:= Rect;
    R.Left:= R.Bottom - R.Top + R.Left + 2;
    S:= cbColors.Items[Index];
    // Если требуется отображать компоненты цвета - добавить их значения к
    // строке с его индексом
    if FShowColorValues then S:= S + Format(' (%d, %d, %d)', [GetRValue(AColor),
                                                              GetGValue(AColor),
                                                              GetBValue(AColor)]);
    with R do
      P:= Point(Left, Top + (Bottom - Top - TextHeight(cbColors.Items[Index])) div 2);
    // Заменить индексы логических цветов на "удобочитаемые"
    case Index of
        0: TextRect(R, P.X, P.Y, 'ByBlock');
      256: TextRect(R, P.X, P.Y, 'ByLayer');
    else
      TextRect(R, P.X, P.Y, S);
    end;
    // Если элемент в фокусе, то...
    if odFocused in State then
    begin
      // ...стереть старую рамку фокуса (которая на весь Rect)
      DrawFocusRect(Rect);
      // ...и нарисовать новую только на текст
      DrawFocusRect(Classes.Rect(R.Left - 2, R.Top, R.Right, R.Bottom));
    end;
  end;
end;

procedure TForm1.chbShowColorValuesClick(Sender: TObject);
begin
  FShowColorValues:= (Sender as TCheckBox).Checked;
  cbColors.Invalidate;
end;